В результате переменная “x” получит значение 30, а переменная “y” - значение 47.

   Запустим программу повторно и наберем на клавиатуре слово “Сергей”. К нашему удивлению, буква “р” не появляется на экране, хотя мы изо всех сил жмем ее на клавиатуре. Увы! Стандартными средствами языка ввести с клавиатуры строчную русскую “р” невозможно. (Мы вернемся к этой проблеме в разделе “Дополнительные возможности”.)

n = 12 + 3
n$ = “12” + “3”
PRINT n, n$

   Из строки символов можно выделить любую ее часть с помощью функции MID$:

   часть = MID$(строка, начальная_позиция, количество_символов)

   Оператор INPUT$(число) вводит заданное число символов без их отображения на экране. Нажимать Enter после ввода не требуется.

‘Запрос пароля

password$ = INPUT$(4)
IF password$ <> “aq” + CHR$(8) + CHR$(27)  THEN STOP

‘Основная программа
   ...

‘------------------Программа ------------------

‘Ждем нажатия клавиши

10 s$ = INKEY$: IF s$ = "" THEN GOTO 10

‘Выделяем и печатаем первый символ

first$ = MID$(s$, 1, 1)
PRINT ASC(first$)

‘Анализируем первый символ

IF first$ = CHR$(27) THEN STOP

‘Выделяем и печатаем второй символ

IF first$ = CHR$(0) THEN
   next$ = MID$(s$, 2, 1)
   PRINT ASC(next$)
END IF
GOTO 10

LF$ = CHR$(0) + CHR$(75)
RT$ = CHR$(0) + CHR$(77)
UP$ = CHR$(0) + CHR$(72)
DN$ = CHR$(0) + CHR$(80)

IF s$ = LF$  THEN
‘Операторы, выполняемые по нажатию стрелки влево
   ...
ELSE IF s$ = RT$  THEN
‘Операторы, выполняемые по нажатию стрелки вправо
   ...
ELSE IF s$ = UP$  THEN
‘Операторы, выполняемые по нажатию стрелки вверх
   ...
ELSE IF s$ = DN$  THEN
‘Операторы, выполняемые по нажатию стрелки вниз
   ...

ELSE
‘Была нажата какая-то другая клавиша
   ...
END IF

   CASE значение_1 : действие_1

   CASE значение_2 : действие_2

   CASE ELSE : иное_действие

‘---------Программа-----------
‘Задаем константы
LF$ = CHR$(0) + CHR$(75)
RT$ = CHR$(0) + CHR$(77)
UP$ = CHR$(0) + CHR$(72)
DN$ = CHR$(0) + CHR$(80)
Esc$ = CHR$(27)
‘Ждем нажатия клавиши
10 s$ = INKEY$: IF s$ = “” THEN GOTO 10
‘Анализируем строку s$
SELECT CASE s$
   CASE LF$: PRINT “Нажата стрелка влево”
   CASE RT$: PRINT “Нажата стрелка вправо”
   CASE UP$: PRINT “Нажата стрелка вверх”
   CASE DN$: PRINT “Нажата стрелка вниз”
   CASE Esc$: STOP
   CASE ELSE: GOTO 10
END SELECT
GOTO 10

‘-------- Программа “Управление окружностью” --------

‘Задаем константы

LF$ = CHR$(0) + CHR$(75)
RT$ = CHR$(0) + CHR$(77)
UP$ = CHR$(0) + CHR$(72)
DN$ = CHR$(0) + CHR$(80)
Esc$ = CHR$(27)

‘Задаем начальные значения переменных

SCREEN 7
x0 = 160: y0 = 100: r0 = 10

‘Рисуем окружность

CIRCLE (x0, y0), r0

‘Ждем нажатия клавиши

10 s$ = INKEY$: IF s$ = “” THEN GOTO 10

‘Анализируем строку s$  и вычисляем параметры “новой” окружности

SELECT CASE s$
   CASE LF$: x = x0 - 5: y = y0: r = r0
   CASE RT$: x = x0 + 5: y = y0: r = r0
   CASE UP$: x = x0: y = y0 - 5: r = r0
   CASE DN$: x = x0: y = y0 + 5: r = r0
   CASE Esc$: STOP
   CASE ELSE: GOTO 10
END SELECT

‘Стираем “старую” и рисуем “новую” окружность

CIRCLE (x0, y0), r0, 0
CIRCLE (x, y), r

‘Заменяем параметры “старой” окружности новыми значениями

x0 = x: y0 = y: r0 = r
GOTO 10

   Запишем программу под именем CIRCLES.BAS, убедимся, что она работает, и попробуем ее улучшить. Во-первых, нерационально повторять в каждом CASE одинаковые присваивания x = x0, y = y0, r = r0. Удобнее сделать все три присваивания перед оператором выбора, а в каждом варианте вычислять только тот параметр, который действительно изменялся. Во-вторых, мы заложили в программу возможность изменения радиуса окружности, но не воспользовались этим. Назначим клавишу “>” для увеличения, а клавишу “<” - для уменьшения радиуса. Наконец, если “стирать” окружность не цветом фона, а любым другим, на экране будет оставаться след - узор из окружностей.

   Оператор GET позволяет запомнить часть графического экрана в некотором массиве, а оператор PUT - вывести запомненное изображение на экран. Синтаксис оператора GET:

   GET (x1, y1)-(x2, y2), массив - запомнить прямоугольную область.

   Точки (x1, y1) и (x2, y2) - две вершины прямоугольника, лежащие на одной из его диагоналей. Размеры прямоугольника и его содержимое запоминаются в массиве.

   Синтаксис оператора PUT:

   PUT (x, y), массив [, способ_вывода] - вывести на экран картинку из массива заданным способом.

   Проиллюстрируем наглядно понятия простой переменной и массива. Простую переменную можно представить в виде ящичка, на котором написано имя переменной (в нашем случае - A). В ящичек можно положить любое число - значение переменной (в нашем случае - 5).

   Массив можно представить как ящик с перегородками. В каждый из получившихся “отсеков” можно положить свое число. Отсеки пронумерованы, поэтому имя каждого отсека состоит из двух частей: общего имени ящика и номера отсека. Но такие обозначения как A₀, A₁, A₂ используются в математике, в языках программирования элемент массива обозначается A(0), A(1), A(2) и т.д.

   DIM имя_массива(номер_последнего_элемента)

   Поскольку нумерация элементов массива в Quick Basic начинается с нуля, то количество элементов массива (длина массива) оказывается на единицу больше номера последнего элемента. Например, DIM A(7) описывает массив из восьми элементов. Иногда, для удобства работы, мы будем “забывать” о нулевом элементе и указывать в описании массива его длину.

   Элементы массива должны иметь значения одного и того же типа. Для указания типа элементов к имени массива добавляется знак $, если элементы массива суть строки символов, или знак %, если все элементы массива - целые числа. (Подробнее о типах данных поговорим в соответствующем разделе.)

   Указатели типа являются частью имени как обычной переменной так и массива, поэтому A% и A$ - это имена разных переменных!

   В операторах GET и PUT будем использовать только массивы целых чисел. Размер массива должен быть достаточно большим, чтобы в него поместилась необходимая информация (сохранилась нужная картинка с экрана). В литературе [1] приводятся точные формулы, но можно пользоваться более простой приближенной формулой

где dx = x2 - x1 + 1, dy = y2 - y1 +1 - размеры (в пикселях) прямоугольной области, полностью закрывающую интересующую нас картинку, по горизонтали и вертикали. Если размер массива, вычисленный по приближенной формуле, окажется недостаточным, Quick Basic выдаст предупреждение “Illegal function call” (“Неверный вызов функции”) и остановит выполнение программы на строке с оператором GET. В этом случае следует несколько увеличить размер массива и запустить программу еще раз.

‘---------------- Программа ------------------
‘----“Копирование прямоугольника” ---

SCREEN 7
DIM a%(     )  ‘Размер массива укажем позже
LINE (20, 20)-(79, 69), 5, BF
GET (20, 20)-(79, 69), a%
SLEEP 1
PUT (120, 20), a%

   Программа выводит на экран закрашенный прямоугольник, для которого dx=60, dy=50. Вычисляя по приближенной формуле размер массива, получим значение 900 (точная формула дает значение 802). Укажем теперь размер массива и запустим программу. На экране появится фиолетовый прямоугольник, а ровно через одну секунду (SLEEP n дает задержку в n секунд) рядом появится его дубликат.

12.2. Способы вывода оператором PUT

   Если в программе “Копирование прямоугольника” в последней строке поставить PUT (30, 30), a% , то на экране появится такая вот картинка.

Мы видим, что в результате наложения двух прямоугольников одного цвета образовалось черное пятно. Это произошло потому, что при выводе картинки оператором PUT над цветом точки экрана и цветом точки картинки, попадающей на это место, производится логическая операция “исключающее или” (краткое обозначение - XOR). Особенность ее состоит в том, что для любого числа n выполняется равенство: n XOR n = 0. Следовательно, наложение точек одинакового цвета даст цвет 0, т.е. цвет фона.

Способ вывода XOR принят в операторе PUT по умолчанию, т.е. если не указан другой способ вывода.Способы вывода определяются последним параметром.

   PSET - вывод картинки без изменения ее цвета. В этом случае никакие операции над цветами картинки и экрана не производятся.

   PRESET - замена цветов картинки на дополнительные. Дополнительный цвет вычисляется по формуле: цвет = 15 - исходный_цвет.

   OR - цвет картинки определяется результатом логической операции “или”.

   AND - цвет картинки определяется результатом логической операции “и”.

FOR x = 30 TO 130 STEP 10
   PUT (x, x), a%
NEXT x

   Нарисуйте границу исходного прямоугольника другим цветом. Измените способ вывода в операторе PUT.

   “Связку” операторов GET и PUT можно использовать для создания периодического узора. Для этого рисуем небольшой прямоугольный фрагмент узора, а затем заполняем фрагментами экран.

‘----------- Программа “Узор” -----------

SCREEN 7
DIM a%(130)

‘Рисуем и запоминаем фрагмент узора

FOR r = 0 TO 10 STEP 2
  LINE (10 - r, 10 - r)- (10 + r, 10 + r), r, B
NEXT r
GET (0, 0)-(20, 20), a%

‘Размножаем фрагмент

CLS
FOR x = 50 TO 250 STEP 20
   FOR y = 40 TO 140 STEP 20
      PUT (x, y), a%, PSET
   NEXT y
NEXT x