Здесь нам поможет “связка” операторов GET и PUT.

   Вспомним, что при выводе оператором PUT картинки на экран, по умолчанию над цветом точки экрана и цветом точки картинки выполняется логическая операция “исключающее или”. При этом на месте точек, совпадающих по цвету, появляются черные “дыры” (точнее, прозрачные “дыры”, через которые виден цвет фона). Значит, если наложить картинку саму на себя, то она исчезнет с экрана. Если фон экрана уже содержит изображение, то при первом выводе картинки ее цвета изменятся (к сожалению!), но зато при втором выводе восстановится фоновое изображение. В ряде случаев изменение цветов картинки нежелательно, тогда приходится использовать другой алгоритм, который мы разберем позже.

1. Задаем константы.
2. Задаем исходное положение картинки и выводим ее на экран.
3. Ждем нажатия клавиши.
4. Вычисляем новое положение картинки.
5. Стираем картинку на старом и выводим ее на новом месте.
6. Обновляем переменные, отвечающие за положение картинки, и переходим к пункту 3.

   Положение картинки на экране задается следующим образом: фиксируется некоторая точка картинки и задаются ее координаты на экране. За эту точку картинка “привязывается” к экрану, поэтому ее иногда называют точкой привязки. В качестве точки привязки возьмем левый верхний угол (вершину) прямоугольной области, в которой размещена картинка.

   В программе на Quick Basic таблицу чисел удобно задать с помощью оператора DATA.

‘Задаем картинку

DATA 0, 0, 7, 7, 7, 7, 7, 0, 0
DATA 0, 8, 0, 0, 0, 0, 0, 8, 0
DATA 8, 0, 0, 8, 0, 8, 0, 0, 8
DATA 8, 0, 3, 3, 0, 3, 3, 0, 8
DATA 8, 0, 0, 0, 0, 0, 0, 0, 8
DATA 8, 0, 0, 12, 12, 12, 0, 0, 8
DATA 0, 8, 0, 0, 0, 0, 0, 8, 0
DATA 0, 0, 8, 8, 8, 8, 8, 0, 0

‘Выводим ее на экран

SCREEN 7
DIM a%(40)
FOR y = 0 TO 7
   FOR x = 0 TO 8
      READ c: PSET (x, y), c
   NEXT x
NEXT y

‘Запоминаем картинку в массиве и очищаем экран

GET (0, 0)-(8, 7), a%
CLS

‘Задаем константы

lf$ = CHR$(0) + CHR$(75)
rt$ = CHR$(0) + CHR$(77)
up$ = CHR$(0) + CHR$(72)
dn$ = CHR$(0) + CHR$(80)

‘Задаем исходное положение картинки и выводим ее на экран

x0 = 165: y0 = 45: x = x0: y = y0
PUT (x0, y0), a%

‘Ждем нажатия клавиши

10 w$ = INKEY$: IF w$ = "" THEN GOTO 10

‘Вычисляем новое положение картинки

SELECT CASE w$
   CASE  lf$: x = x0 - 5
   CASE  rt$: x = x0 + 5
   CASE  up$: y = y0 - 5
   CASE  dn$:  y = y0 + 5
   CASE CHR$(27): STOP
   CASE ELSE: GOTO 10
END SELECT

‘Стираем картинку на старом и выводим на новом месте

PUT (x0, y0), a%
PUT (x, y), a%

‘Обновляем переменные

x0 = x: y0 = y
GOTO 10

   Запишем программу в файл ROZICA.BAS и попробуем ее выполнить. Пока “рожица” бегает по экрану - все хорошо. Но при попытке увести ее за экран появляется сообщение об ошибке “Illegal function call” и высвечивается строка с оператором PUT(x, y), a%. Что ж, будем контролировать значения переменных x и y, а при необходимости, восстанавливать прежние значения. Это просто для случаев движения влево или вверх, так как (x, y) - координаты левого верхнего угла картинки:

Если же мы движемся вправо или вниз, то необходимо чтобы правый нижний угол картинки еще помещался на экране. Чтобы не менять во всей программе параметры экрана при их изменениях, введем переменные xmax - номер самой правой точки экрана и ymax - номер самой нижней точки экрана (для SCREEN 7 xmax = 319, ymax = 199). То же самое относится и к изменению размеров картинки - пусть она при выводе в левый верхний угол экрана занимает место от 0 до dx по горизонтали и от 0 до dy по вертикали. Тогда проверочные условия примут вид:

   Естественно значения dx и dy задавать после операторов DATA, а переменные xmax и ymax инициализировать после оператора SCREEN. В результате доработок получим следующую программу:

‘ ---------- Программа “Рожица” ----------

‘Задаем картинку

DATA 0, 0, 7, 7, 7, 7, 7, 0, 0
DATA 0, 8, 0, 0, 0, 0, 0, 8, 0
DATA 8, 0, 0, 8, 0, 8, 0, 0, 8
DATA 8, 0, 3, 3, 0, 3, 3, 0, 8
DATA 8, 0, 0, 0, 0, 0, 0, 0, 8
DATA 8, 0, 0, 12, 12, 12, 0, 0, 8
DATA 0, 8, 0, 0, 0, 0, 0, 8, 0
DATA 0, 0, 8, 8, 8, 8, 8, 0, 0
dx = 8: dy = 7

‘Выводим ее на экран

SCREEN 7: xmax = 319: ymax = 199
DIM a%(40)
FOR y = 0 TO dy
   FOR x = 0 TO dx
      READ c: PSET (x, y), c
   NEXT x
NEXT y

‘Запоминаем картинку в массиве и очищаем экран

GET (0, 0)-(dx, dy), a%
CLS

‘Задаем исходное положение картинки и выводим ее на экран

x0 = 165: y0 = 45: x = x0: y = y0
PUT (x0, y0), a%

‘Ждем нажатия клавиши

10 w$ = INKEY$: IF w$ = "" THEN GOTO 10

‘Вычисляем новое положение картинки

SELECT CASE w$
   CASE   lf$: x = x0 - 5: IF x < 0 THEN x = x0
   CASE  up$: y = y0 - 5: IF y < 0 THEN y = y0
   CASE  rt$: x = x0 + 5: IF x +  dx > xmax THEN x = x0
   CASE  dn$: y = y0 + 5: IF y + dy > ymax THEN y = y0
   CASE CHR$(27): STOP
   CASE ELSE: GOTO 10
END SELECT

‘Стираем картинку на старом и выводим на новом месте

PUT (x0, y0), a%
PUT (x, y), a%

‘Обновляем переменные

x0 = x: y0 = y
GOTO 10

dx = 7: dy = 15

SCREEN 7: xmax = 319: ymax = 199
DIM a%(40)
FOR y = 0 TO dy
   FOR x = 0 TO dx
      READ c: IF c = 1 THEN c = 10  ‘Изменение цвета курсора
      PSET (x, y), c
   NEXT x
NEXT y

‘Запоминаем картинку в массиве и очищаем экран

GET (0, 0)-(dx, dy), a%
CLS

LINE (0, 0)-(xmax, ymax), 15, B
LINE (80, 0)-(80, ymax), 15
LINE (10, 10)-(70, 160), 15, B<

‘Заполняем палитру красками

c = 14
FOR y = 20 TO 150 STEP 10
   LINE (10, y)-(80, y), 15
   PAINT (40, y-5), c, 15
   c = c - 1
NEXT y

‘Индикатор

CIRCLE (40,180), 10, 15

FOR r = 10 TO 100 STEP 15
   CIRCLE (200, 100), r, 15
NEXT r

   Чтобы контурный рисунок не мог нечаянно выйти за пределы основного поля, можно ограничить область вывода с помощью оператора VIEW:

   VIEW (x1, y1)-(x2, y2) - устанавливает прямоугольное окно вывода с новой системой координат, начало которой располагается в левом верхнем углу окна. Относительные (локальные) координаты позволяют не задумываться о том, в каком месте экрана будет в дальнейшем расположен рисунок. Если по каким-либо причинам требуется сохранить в окне систему координат экрана, то следует использовать вариант

   VIEW SCREEN (x1, y1)-(x2, y2).

   Чтобы восстановить возможность вывода на весь экран, следует применить оператор VIEW без параметров.

‘Задаем константы

lf$ = CHR$(0) + CHR$(75)
rt$ = CHR$(0) + CHR$(77)
up$ = CHR$(0) + CHR$(72)
dn$ = CHR$(0) + CHR$(80)

‘Задаем исходное положение курсора и выводим его на экран

x0 = 165: y0 = 45: x = x0: y = y0
PUT (x0, y0), a%

‘Ждем нажатия клавиши

10 w$ = INKEY$: IF w$ = "" THEN GOTO 10

‘Вычисляем новое положение курсора

SELECT CASE w$
   CASE   lf$: x = x0 - 2: IF x < 0 THEN x = x0
   CASE  up$: y = y0 - 2: IF y < 0 THEN y = y0
   CASE  rt$: x = x0 + 2: IF x +  dx > xmax THEN x = x0
   CASE  dn$: y = y0 + 2: IF y + dy > ymax THEN y = y0
   CASE CHR$(27): STOP
   CASE ELSE: GOTO 10
END SELECT

‘Стираем курсор на старом и выводим на новом месте

PUT (x0, y0), a%
PUT (x, y), a%

‘Обновляем переменные

x0 = x: y0 = y
GOTO 10

   Добавим теперь в оператор выбора реакцию программы на нажатие клавиши Enter. Эту клавишу мы нажимаем в двух случаях: когда хотим выбрать цвет закрашивания, и когда указываем область для закраски. Различить эти случаи легко: в первом случае острие стрелки (точка x0, y0) находится в прямоугольнике (10, 10)-(70, 160) - это границы палитры; во втором - в прямоугольнике (80, 0)-(xmax, ymax) - это границы основного поля.

   CASE CHR$(13)
      IF x0 > 10 AND x0 < 70 AND y0 > 10 AND y0 < 160 THEN
        ‘Определяем цвет краски на палитре
         c = 15 - y0 \ 10
        ‘Прячем курсор
         PUT (x0, y0), a%
        ‘закрашиваем индикатор
         PAINT (40, 180), c, 15
        ‘и восстанавливаем курсор на том же месте
         PUT (x0, y0), a%
      END IF

   Получить формулу, которая связывает номер цвета с расположением краски на палитре, поможет следующая таблица:

   Легко видеть, что номер интервала и цвет в сумме равны 15 в любой строке таблицы, а номер интервала равен количеству полных десятков в числе y. Вычислить номер интервала можно с помощью операции целочисленного деления: n = y \ 10. После этого цвет краски получается по формуле c = 15 - n.

   Заметим, что простота формулы есть результат простой закономерности в расположении цветов палитры. В других случаях может оказаться проще “считывать” цвет непосредственно с экрана, используя функцию POINT.

   POINT(x, y) - возвращает цвет пикселя экрана с координатами (x, y).

   Зачем потребовалось стирать курсор перед закрашиванием индикатора? Дело в том, что при закраске области может оказаться, что курсор задевает ее границу. В этом месте граница исчезнет, и через образовавшуюся “дыру” краска вытечет за пределы области. Поэтому перед любым закрашиванием мы будем убирать курсор с экрана, а после - возвращать на экран. (“Прятать” курсор придется и при определении функцией POINT цвета точки (x0, y0), которая находится под курсором.)

      IF x0 > 80 AND x0 < xmax AND y0 > 0 AND y0 < ymax THEN
        ‘Прячем курсор
         PUT (x0, y0), a%
        ‘Закрашиваем область
         PAINT (x0, y0), c, 15
        ‘Восстанавливаем курсор
         PUT (x0, y0), a%
      END IF

   При наличии монитора VGA дополнительно можно пользоваться графическими режимами SCREEN 10, 11, 12 или 13.

   SCREEN 10 - разрешение 640х350 точек, цветовая палитра - черно-белая с возможностью мигания ( 0 - черный цвет, 1 - белый цвет, 2 - мигающий ).

   SCREEN 11 - разрешение 640х480 точек, цветовая палитра - черно-белая ( 0 - черный цвет, 1 - белый цвет).

   SCREEN 12 - разрешение 640х350 точек, цветовая палитра - 16 цветов. В этом и следующем (SCREEN 13) режиме оператор COLOR имеет несколько другой синтаксис:

   COLOR цвет_рисования - устанавливает цвет “по умолчанию” для графических операторов PSET, LINE, CIRCLE и др.

   SCREEN 13 - разрешение 320х200 точек, цветовая палитра может содержать до 256 цветов (в Quick Basic - 248). По количеству точек этот режим совпадает с режимом SCREEN 7, но каждая точка может быть окрашена в один из 248 цветов.

   Познакомимся поближе с последним режимом. Если в программе “Раскрашка” заменить SCREEN 7 на SCREEN 13, то при выполнении оператора

появится сообщение “Illegal function call”, что означает, что курсор не помещается в массив a%. А почему? Дело в том, что для задания любого из 16 цветов необходимо 4 бита информации (16 = 2⁴), а для задания 256 цветов - 8 бит (256 = 2⁸), т.е. при работе в режиме SCREEN 13 массив a% должен быть вдвое больше, чем в SCREEN 7. После этого программа заработает, но в ней все останется по-прежнему! Чтобы изменить палитру цветов нужно взять цвета с номерами, отличными от 0 - 15. Сразу же за этими номерами идет палитра оттенков серого цвета - от цвета номер 16 (черного) до цвета номер 31 (белого). Изменим начальное значение с = 14 на с = 31 (Quick Basic различает цвета с номерами 31 и 15, хотя “по виду” они одинаковы!) и перепишем фрагмент программы для определения цвета закрашивания:

        ‘Определяем цвет краски на палитре
        ‘Прячем курсор,
         PUT (x0, y0), a%
        ‘определяем цвет,
         c = POINT(x0, y0)
        ‘закрашиваем индикатор
         PAINT (40, 180), c, 15
        ‘и восстанавливаем курсор на том же месте
         PUT (x0, y0), a%

        ‘Определяем цвет краски на палитре
        ‘Прячем курсор,
         PUT (x0, y0), a%
        ‘определяем цвет,
         c0 = POINT(x0, y0)
         IF c0 <> 15 THEN
            c = c0
           ‘закрашиваем индикатор
            PAINT (40, 180), c, 15
         END IF
        ‘и восстанавливаем курсор на том же месте
         PUT (x0, y0), a%

   Задание. Напишите программу для вывода на экран всех палитр в режиме SCREEN 13. Подберите свою палитру цветов для программы “Раскрашка” и вставьте ее в программу с помощью оператора DATA. Измените программу так, чтобы она при рисовании палитры “читала” цвет из списка данных.